Here's a simple example of how to import User-Defined Properties from Excel


To run it:

1) bring up the Script Explorer

2) right click on "User Defined" and select "New Script"

3) copy/paste the script below into the edit control

4) hit the run button (the first icon in the toolbar above the edit control)

Note: you can undo/redo the effects of this script as with any Model changes


/********** start of script *************/

Sub Evaluate_OnLoad()
	Set Context = CreateObject("SCF.ScriptContext")
	Set Framework = CreateObject("SCF.ScriptFramework")
	Set ThisScript = Context.Object
	Set Model = ThisScript.Model
	Set Document = Context.ScriptDocument

	Set ExcelApp = CreateObject("Excel.Application")
	ExcelApp.Visible = false
	File = InputBox("Please enter the Excel file location")
	ExcelApp.Workbooks.Open File, false, true

	intRow = 2
	Model.BeginTransaction("Update UDP Values")
	Do Until ExcelApp.Cells(intRow,1).Value = ""
		TableStr = ExcelApp.Cells(intRow, 1).Value
		UDPStr = ExcelApp.Cells(intRow, 2).Value
		ValueStr = ExcelApp.Cells(intRow, 3).Value
		Set Table = Model.AsObject.ChildByName("Table", TableStr)
		If Not Table Is Nothing Then
			If ValueStr <> Table.Property(UDPStr).AsString Then
				Set StringProp = Model.CreatePropertyValue("Table", UDPStr)
				If Not StringProp Is Nothing Then
			        StringProp.FromString(ValueStr)
		            Table.SetProperty UDPStr, StringProp
					Document.Write("Table: " & TableStr & " Value " & UDPStr & " Set to " & ValueStr & vbLf)
				End If
			End If
		End If
		intRow = intRow + 1
	Loop
	Model.EndTransaction()
End Sub