This script is written to be a Post-Script type for a table.  To set for all Tables:

1) bring up the Script Explorer

2) click on SQL Server/Table/Post Script

3) copy/paste the script below into the Property Browser edit control

4) select a Table that has a UDP (or has Columns that do)

5) select SQL tab and the Post Script for Script Type

/********** start of script *************/

Sub WriteExtendedProp(Obj, Options, Document, PropName)
	If Not Obj.Property(PropName) Is Nothing Then
		If Trim(Obj.Property(PropName).AsString) <> "" Then
			Document.Write("EXEC sp_addextendedproperty ")
			Document.Write("@name = '" & PropName & "', @value = '" & Obj.Property(PropName).AsString & "',")
			Document.Write(vbLf & vbTab)
			If Obj.TypeName = "Column" Then
				Set Table = TableOwner(Obj)
			Else
				Set Table = Obj
			End If
			Document.Write("@level0type = 'Schema', @level0name = '" & Table.Property("Schema").AsString & "',")
			Document.Write(vbLf & vbTab)
			Document.Write("@level1type = 'Table', @level1name = '" & Table.Name & "'")
			If Obj.TypeName = "Column" Then
				Document.Write("," & vbLf & vbTab)
				Document.Write("@level2type = 'Column', @level2name = '" & Obj.Name & "'")
			End If
			Document.Write(";")
			AddDelim Options, Document
			Document.Write(vbLf)
		End If
	End If
End Sub

Sub WriteColumnExtendedProps(Column, Options, Document, MetaColumn) 
    HasSubCols = False
    For Each SubColumn In Column.Children("Column")
        WriteColumnExtendedProps SubColumn, Options, Document, MetaColumn
        HasSubCols = True
    Next
    If Not HasSubCols Then
        For Each MetaProp In MetaColumn.MetaProperties
            If MetaProp.IsUserDefined Then
                WriteExtendedProp Column, Options, Document, MetaProp.Name
            End If
        Next
    End If
End Sub

Sub Evaluate_OnLoad()
	Set Context = CreateObject("SCF.ScriptContext")
	Set Document = Context.ScriptDocument
	Set Table = Context.Object
	Set Options = Context.Options

    Set Model = Table.Model
    Set MetaModel = Model.MetaModel
    Set MetaTable = MetaModel.MetaObject("Table")
    For Each MetaProp In MetaTable.MetaProperties
        If MetaProp.IsUserDefined Then
             WriteExtendedProp Table, Options, Document, MetaProp.Name
        End If
    Next

    Set MetaColumn = MetaModel.MetaObject("Column")
    For Each Column In Table.Children("Column")
         WriteColumnExtendedProps Column, Options, Document, MetaColumn
    Next
End Sub